Add preliminary cmake files

diff --git a/CMakeLists.txt b/CMakeLists.txt
new file mode 100644 (file)
index 0000000..7224ecd
--- /dev/null
+++ b/CMakeLists.txt
@@ -0,0 +1,25 @@
+cmake_minimum_required (VERSION 2.8)
+project(daqdata)
+
+# check for in-source build, forbid it!
+if(CMAKE_BINARY_DIR STREQUAL CMAKE_SOURCE_DIR AND NOT MSVC_IDE)
+  message(FATAL_ERROR "\nIn-source build attempt detected!\n"
+    "Please create a new directory (e.g. build) and run `cmake ..`.\n"
+    "Also don't forget to delete the created CMakeCache.txt and CMakeFiles dir"
+    )
+endif()
+    
+include (cmake/settings.cmake)
+
+message(STATUS "*** Build Type:      " ${CMAKE_BUILD_TYPE})
+message(STATUS "*** Compiler Flags:  " ${DEFAULT_COMPILE_FLAGS})
+message(STATUS "*** Install libs to: " ${LIBRARY_OUTPUT_PATH})
+message(STATUS "*** Install bin to:  " ${EXECUTABLE_OUTPUT_PATH})
+
+# include some additional "find_package" routines and helpers...
+set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
+
+add_subdirectory(allParam)
+add_subdirectory(compat)
+add_subdirectory(hadaq)
+

diff --git a/cmake/Modules/FindEPICS.cmake b/cmake/Modules/FindEPICS.cmake
new file mode 100644 (file)
index 0000000..d7b92a2
--- /dev/null
+++ b/cmake/Modules/FindEPICS.cmake
@@ -0,0 +1,144 @@
+# - Find EPICS instalation
+#
+# Variables defined by this module:
+#
+#   EPICS_FOUND               System has ROOT, this means the root-config 
+#                            executable was found.
+#
+#   EPICS_INCLUDES            Same as above,
+#
+#   EPICS_LIBRARIES           Link to these to use the ROOT libraries, not cached
+#
+#   EPICS_LIBRARY_DIR         The path to where the ROOT library files are.
+#
+
+Message(STATUS "Looking for EPICS...")
+
+# this path should contain the "base" and "extensions" directory
+Set(EPICS_BASE_SEARCHPATH
+  $ENV{EPICS_BASE}
+  /home/epics/base
+  /opt/epics/base
+)
+
+# this search path is also appended by ${EPICS_BASE}/../extensions
+# if EPICS_BASE was found at all
+Set(EPICS_EXTENSIONS_SEARCHPATH
+  $ENV{EPICS_EXTENSIONS}
+)
+
+Set(EPICS_FOUND FALSE)
+Set(EPICS_DEFINITIONS "")
+
+find_path(EPICS_BASE NAMES EpicsHostArch 
+             PATHS ${EPICS_BASE_SEARCHPATH}
+             PATH_SUFFIXES startup
+             NO_DEFAULT_PATH
+            )
+if(NOT EPICS_BASE)
+  Message(STATUS "Looking for EPICS... - EPICS_BASE not found")
+  Message(STATUS "Looking for EPICS... - Environment EPICS_BASE set?")
+  if(EPICS_FIND_REQUIRED)    
+    message(FATAL_ERROR "Stopping here.")
+  endif()
+  return()
+endif()
+
+# strip off subdirectory "startup"
+get_filename_component(EPICS_BASE ${EPICS_BASE} PATH)
+
+set(EPICS_HOST_ARCH_EXE "${EPICS_BASE}/startup/EpicsHostArch")
+
+Execute_Process(COMMAND ${EPICS_HOST_ARCH_EXE} 
+  OUTPUT_VARIABLE EPICS_HOST_ARCH
+  OUTPUT_STRIP_TRAILING_WHITESPACE
+  )
+
+if(NOT EPICS_HOST_ARCH)
+  message(FATAL_ERROR "Cannot determine EPICS host arch")  
+endif()
+
+message(STATUS "Looking for EPICS... - Found ${EPICS_BASE}")
+message(STATUS "Looking for EPICS... - Found host arch ${EPICS_HOST_ARCH}")
+
+# try guessing the extension directory
+# should contain a Makefile
+list(APPEND EPICS_EXTENSIONS_SEARCHPATH "${EPICS_BASE}/../extensions")
+
+find_path(EPICS_EXTENSIONS NAMES Makefile 
+  PATHS ${EPICS_EXTENSIONS_SEARCHPATH}
+  NO_DEFAULT_PATH
+  )
+if(NOT EPICS_EXTENSIONS)
+  message(FATAL_ERROR "No EPICS Extensions found. EPICS incomplete?")
+endif()
+message(STATUS "Looking for EPICS... - Found ${EPICS_EXTENSIONS}")
+
+# find the includes directories
+find_path(EPICS_BASE_INCLUDE NAMES tsDefs.h 
+  PATHS "${EPICS_BASE}/include"
+  NO_DEFAULT_PATH
+  )
+if(NOT EPICS_BASE_INCLUDE)
+  message(FATAL_ERROR "No EPICS base include found. EPICS incomplete?")
+endif()
+
+find_path(EPICS_BASE_INCLUDE_OS NAMES osdTime.h 
+  PATHS "${EPICS_BASE_INCLUDE}/os/${CMAKE_SYSTEM_NAME}"
+  NO_DEFAULT_PATH
+  )
+if(NOT EPICS_BASE_INCLUDE_OS)
+  message(FATAL_ERROR "No EPICS base include (os-dependent) found. "
+    "EPICS incomplete or unsupported platform?")
+endif()
+
+# this is extension specific, can be generalized later
+find_path(EPICS_EXTENSIONS_INCLUDE NAMES ezca.h 
+  PATHS "${EPICS_EXTENSIONS}/include"
+  NO_DEFAULT_PATH
+  )
+if(NOT EPICS_EXTENSIONS_INCLUDE)
+  message(FATAL_ERROR "No EPICS extensions include with ezca.h found. "
+    "EZCA not correctly installed?")
+endif()
+
+# find required libraries
+# -lca -lCom -lezca
+# this is a bit verbose (the next library needed will trigger macro creation :)
+set(EPICS_LIBRARY_DIR ${EPICS_BASE}/lib/${EPICS_HOST_ARCH}
+  ${EPICS_EXTENSIONS}/lib/${EPICS_HOST_ARCH})
+
+find_library(EPICS_LIB_CA NAMES ca
+  PATHS ${EPICS_LIBRARY_DIR}
+  NO_DEFAULT_PATH)  
+if(NOT EPICS_LIB_CA)
+  message(FATAL_ERROR "EPICS libca not found. "
+    "EPICS not correctly installed?")
+else()
+  list(APPEND EPICS_LIBRARIES ${EPICS_LIB_CA})
+endif()
+
+find_library(EPICS_LIB_COM NAMES Com
+  PATHS ${EPICS_LIBRARY_DIR}
+  NO_DEFAULT_PATH)  
+if(NOT EPICS_LIB_COM)
+  message(FATAL_ERROR "EPICS libCom not found. "
+    "EPICS not correctly installed?")
+else()
+  list(APPEND EPICS_LIBRARIES ${EPICS_LIB_COM})
+endif()
+
+find_library(EPICS_LIB_EZCA NAMES ezca
+  PATHS ${EPICS_LIBRARY_DIR}
+  NO_DEFAULT_PATH)  
+if(NOT EPICS_LIB_EZCA)
+  message(FATAL_ERROR "EPICS ezca not found. "
+    "EPICS extensions EZCA not correctly installed?")
+else()
+  list(APPEND EPICS_LIBRARIES ${EPICS_LIB_EZCA})
+endif()
+
+
+set(EPICS_INCLUDES ${EPICS_BASE_INCLUDE} ${EPICS_BASE_INCLUDE_OS}
+  ${EPICS_EXTENSIONS_INCLUDE})
+set(EPICS_FOUND TRUE)

diff --git a/cmake/settings.cmake b/cmake/settings.cmake
new file mode 100644 (file)
index 0000000..d6315b5
--- /dev/null
+++ b/cmake/settings.cmake
@@ -0,0 +1,30 @@
+# this is a hard requirement...will be sorted out later
+#set(CMAKE_SHARED_LINKER_FLAGS "-Wl,--no-undefined")
+
+# every subdirectory has its own bin/lib path
+# this should be changed to one "global" directory...
+if(NOT DEFINED EXECUTABLE_OUTPUT_PATH)
+       set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin")
+endif()
+
+if(NOT DEFINED LIBRARY_OUTPUT_PATH)
+       set(LIBRARY_OUTPUT_PATH "${CMAKE_BINARY_DIR}/lib")
+endif()
+
+# we check for empty string here, since the variable
+# is indeed defined to an empty string
+if(NOT CMAKE_BUILD_TYPE)
+  # this also reflects this default in the GUI
+       SET(CMAKE_BUILD_TYPE Release CACHE STRING
+    "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
+    FORCE)
+endif()
+
+# really no optimization in debug mode
+if(CMAKE_COMPILER_IS_GNUCXX)
+  set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -O0")
+endif()
+
+string(TOUPPER ${CMAKE_BUILD_TYPE} BUILD_TYPE)
+set(DEFAULT_COMPILE_FLAGS ${CMAKE_CXX_FLAGS_${BUILD_TYPE}})
+